xlsvbah12.3

Attribute VB_Name = "mod3Antwoorden"

Option Explicit

' Opdracht 1: maak een procedure die de cellen - van het gebruikte bereik van het werkblad opdrachten - wit maakt

Sub Antwoord1()

    Dim wbWerkboek As Workbook
    Dim wsWerkblad As Worksheet
    Dim rngBereik As Range
    
    Set wbWerkboek = ActiveWorkbook
    Set wsWerkblad = wbWerkboek.Sheets("Opdrachten")
    Set rngBereik = wsWerkblad.UsedRange
    
    rngBereik.Interior.Color = vbWhite

End Sub

' Opdracht 2: maak een procedure die de cellen - van het werkblad opdrachten met de letter C - geel maakt

Sub Antwoord2()

    Dim wbWerkboek As Workbook
    Dim wsWerkblad As Worksheet
    Dim rngBereik As Range
    
    Set wbWerkboek = ActiveWorkbook
    Set wsWerkblad = wbWerkboek.Sheets("Opdrachten")
    Set rngBereik = wsWerkblad.Range("A11").CurrentRegion
   
    rngBereik.Interior.Color = vbYellow

End Sub

' Opdracht 3: maak een procedure die de cellen - van het werkblad opdrachten met de letters AB - groen maakt

Sub Antwoord3()

    Dim wbWerkboek As Workbook
    Dim wsWerkblad As Worksheet
    Dim rngBereikA As Range
    Dim rngBereikB As Range
    
    Set wbWerkboek = ActiveWorkbook
    Set wsWerkblad = wbWerkboek.Sheets("Opdrachten")
    Set rngBereikA = wsWerkblad.Range("C1:F8")
    Set rngBereikB = wsWerkblad.Range("E6:H14")
    
    Intersect(rngBereikA, rngBereikB).Interior.Color = vbGreen

End Sub

' Opdracht 4: maak een procedure die de cellen - van het werkblad opdrachten met de letters A - blauw maakt

Sub Antwoord4()

    Dim wbWerkboek As Workbook
    Dim wsWerkblad As Worksheet
    Dim rngBereik As Range
    Dim rngCel As Range
    
    Set wbWerkboek = ActiveWorkbook
    Set wsWerkblad = wbWerkboek.Sheets("Opdrachten")
    Set rngBereik = wsWerkblad.UsedRange

    For Each rngCel In rngBereik.Cells
        If rngCel.Value = "A" Then rngCel.Interior.Color = vbBlue
    Next rngCel

End Sub

Sub Antwoord4b()

    Dim wbWerkboek As Workbook
    Dim wsWerkblad As Worksheet
    Dim strAdres As String
    Dim rngCel As Range

    Set wbWerkboek = ActiveWorkbook
    Set wsWerkblad = wbWerkboek.Sheets("Opdrachten")

    With wsWerkblad.Cells
        Set rngCel = .Find(What:="A", LookIn:=xlValues, _
                        LookAt:=xlWhole, SearchOrder:=xlByRows, _
                        MatchCase:=False, SearchFormat:=False)

        If Not rngCel Is Nothing Then
            strAdres = rngCel.Address
            Do
                rngCel.Interior.Color = vbBlue
                Set rngCel = .FindNext(rngCel)
                If rngCel Is Nothing Then Exit Do
            Loop Until rngCel.Address = strAdres
        End If
    End With

End Sub